# define module command and surrounding initial environment (default value
# for MODULESHOME, MODULEPATH, LOADEDMODULES and parse of init/.modulespath)
eval "`/usr/bin/tclsh /usr/share/Modules/libexec/modulecmd.tcl csh autoinit`"

if ( $?tcsh && $?prompt && -r /usr/share/Modules/init/tcsh_completion ) then
   source /usr/share/Modules/init/tcsh_completion
endif

# setup ENV variables to get module defined in sub-shells (works for 'sh'
# and 'ksh' in interactive mode and 'sh' (zsh-compat), 'bash' and 'ksh'
# (zsh-compat) in non-interactive mode.
setenv ENV /usr/share/Modules/init/profile.sh
setenv BASH_ENV /usr/share/Modules/init/bash

if ( ":${PATH}:" !~ '*:/usr/share/Modules/bin:*' ) then
   if ( "$PATH" == '' ) then
      setenv PATH /usr/share/Modules/bin
   else
      setenv PATH "/usr/share/Modules/bin:$PATH"
   endif
endif

if ( $?MANPATH ) then
   set manpath = $MANPATH
else
   set manpath = `manpath`
endif
if ( ":${manpath}:" !~ '*:/usr/share/man:*' ) then
   if ( "$manpath" == '' ) then
      setenv MANPATH /usr/share/man
   else
      setenv MANPATH "/usr/share/man:$manpath"
   endif
endif
unset manpath
