# Maintainer (Arch:community): Felix Yan <felixonmars@archlinux.org>
# Contributor (Arch): Timofey Titovets <Nefelim4ag@gmail.com>
# Maintainer: Luke T. Shumaker <lukeshu@parabola.nu>

# Rationale for inclusion in [pcr]: Several boxes lukeshu is
# reponsible for (including winston.parabola.nu) still use it, and I
# don't care to migrate them away right now.
#
# - 2020-08-13: Most recent upstream release (v4.4.0)
# - 2023-05-19: Removed from [community]
# - 2023-09-04: Added to AUR

pkgname=systemd-swap
pkgver=4.4.0
pkgrel=4
pkgdesc="Script for creating hybrid swap space from zram swaps, swap files and swap partitions."
arch=('any')
url="https://github.com/Nefelim4ag/systemd-swap"
license=('GPL3-3.0-or-later')
depends=('python-systemd' 'python-sysv_ipc' 'systemd' 'util-linux')
backup=('etc/systemd/swap.conf')
source=("$pkgname-$pkgver.tar.gz::https://github.com/Nefelim4ag/systemd-swap/archive/$pkgver.tar.gz"
        0001-Only-use-one-zram-device-on-modern-kernels.patch
        0002-zswap-Proper-version-checks-for-zswap_compressor-and.patch)
sha512sums=('39cf297d0d82f4d5fbae64f323bda2c286dd24665321892f068dc5bceea4ea5ddcacdcef14576cab869edbed7d258de759baec36535403051bb2b925406db0b3'
            '76c82aa533a538a0f5d39bb52ab11cc6a1ab14e2853f612101989cc6e744f9601e8d209e95e0e60e2e9978d337868140dddb5c6d9b82041ef2e5f9e659493add'
            'd1dc5ec63339e1bfa740b23e04eb5b0ad135f643d8d0ea8577a2021276d7df7358c7169a6817f8ba08ff76735724e34ed5fcdfca67cfaaea890c7ba0ae6749ca')

prepare() {
  cd systemd-swap-$pkgver

  local patchfile
  for patchfile in ../*.patch; do 
    patch -Np1 -i "$patchfile"
  done
}

build() {
  cd systemd-swap-$pkgver
  make
}

check() {
  cd systemd-swap-$pkgver
  ./systemd-swap status
}

package() {
  cd systemd-swap-$pkgver
  make DESTDIR="$pkgdir" install
}
