# Maintainer (Arch:community): Felix Yan <felixonmars@archlinux.org>
# Maintainer (AUR): None
# Maintainer: Luke T. Shumaker <lukeshu@parabola.nu>

# Rationale for inclusion in [pcr]: Dependency of pcr/systemd-swap.
#
# - 2021-01-17: Most recent upstream release (v1.1.0)
# - 2023-05-19: Removed from [community]
# - 2024-02-24: Added to AUR

pkgname=python-sysv_ipc
pkgver=1.1.0
pkgrel=7
pkgdesc="System V IPC primitives (semaphores, shared memory and message queues) for Python"
url="http://semanchuk.com/philip/sysv_ipc/"
license=('BSD-3-Clause')
arch=('x86_64' 'i686' 'armv7h')
depends=('python')
makedepends=('python-setuptools')
source=("http://semanchuk.com/philip/sysv_ipc/sysv_ipc-$pkgver.tar.gz")
sha512sums=('30615c7fcd2ce45b5602fbd61bc2061f5fd44eb7d8ec0bcfd2979e2e750b0f7093bad938cb715ba65dac306c576f76973d462ecc52785fc8f7bacc70a84d79ff')

build() {
  cd sysv_ipc-$pkgver
  python setup.py build
}

check() {
  cd sysv_ipc-$pkgver
  PYTHONPATH=$(echo "$PWD/build/lib.linux"-*) python -m unittest discover
}

package() {
  cd sysv_ipc-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1
  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
}
