# Copyright (C) 2019-2023 Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>
# This program is free software: you can redistribute it and/or modify
# it under the terms of the CC0 1.0 License.
# Maintainer: Parabola Hackers <dev@lists.parabola.nu>

pkgname=guix-installer
pkgver=1.5.0
_pkgver=v${pkgver}
pkgrel=1
pkgdesc="A command line installer for Guix"
arch=(any)
url="https://www.gnu.org/software/guix/"
license=('GPL-3.0-or-later')
depends=('coreutils'
         'glibc'
         'gnupg'
         'grep'
         'sed'
         'shadow'
         'tar'
         'wget'
         'which'
         'xz')

source=("https://cgit.git.savannah.gnu.org/cgit/guix.git/plain/etc/guix-install.sh?h=${_pkgver}"
        "https://cgit.git.savannah.gnu.org/cgit/guix.git/plain/COPYING?h=${_pkgver}")

sha256sums=('7f544e48c9082baf489207ac506acd78bf251355bbafffd744498e658880879d'
            '8ceb4b9ee5adedde47b31e975c1d90c73ad27b6b165a1dcd80c7c545eb65b903')
sha512sums=('c79da2d8b29a13ff017b0ac622739052696385a1e7f1bec0d136051b1864480c7815356682c3099f8c5bd1391de0f41a821a534a864f5bca93fece8f8e1a2e99'
            '7633623b66b5e686bb94dd96a7cdb5a7e5ee00e87004fab416a5610d59c62badaf512a2e26e34e2455b7ed6b76690d2cd47464836d7d85d78b51d50f7e933d5c')

prepare() {
    mkdir -p "${pkgname}-${_pkgver}"
    cd "${pkgname}-${_pkgver}"
    cp "${srcdir}/guix-install.sh?h=${_pkgver}" guix-install.sh
    cp "${srcdir}/COPYING?h=${_pkgver}" COPYING
}

package() {
    cd "${pkgname}-${_pkgver}"
    install -d "${pkgdir}/usr/bin"
    install -m 755 guix-install.sh -t "${pkgdir}/usr/bin"

    install -d "${pkgdir}/usr/share/licenses/${pkgname}"
    install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}
